Aufruf des generierten Moduls aus einem SPS-Projekt

Konfiguration in Simulink

In den Einstellungen unter Tc Advanced wird zunächst CallBy auf Module gestellt (kann auch im TwinCAT Engineering nachträglich geändert werden).

Ab TE1400 Version 1.2.1230 ist der Parameter Skip caller verification sichtbar.

Ab TE1400 Version 1.2.1216.0 finden Sie den Parameter PLC Function Block (TcCOM wrapper):

Hier kann zwischen folgenden Optionen gewählt werden:

Der modulspezifische Funktions-Baustein

FB_<ModuleName> ist abgeleitet von FB_TcMatSimObject, stellt also auch die oben beschriebenen Methoden und Properties zur Verfügung. Zusätzlich sind hier folgende Properties implementiert:

Public Properties:

Hinweise bezüglich FB with properties for all parameters

Wird unter Tc Interfaces im Bereich Parameter access der Punkt Process image auf Internal DataArea gesetzt, wird eine Property für die Gesamtheit aller Parameter angelegt. Diese müssen dann als Gesamtheit gelesen und geschrieben werden:

PROGRAM MAIN
VAR
    // declare function block (details see below)
    fbControl : FB_TctSmplTempCtrl(oid := 16#01010010);
    // local PLC variable
    ModelParameters : P_TctSmplTempCtrl_T;
END_VAR

// read all model parameters
ModelParameters := fbControl.ModelParameters_Online;
// change value
ModelParameters.Kp := 20;
// write all model parameters
fbControl.ModelParameters_Online := ModelParameters;

Wird unter Tc Interfaces im Bereich Parameter access der Punkt Process image auf No DataArea gesetzt, wird für jeden Modelparameter eine eigene Property erzeugt. Diese können dann direkt ohne lokale PLC Variable gelesen und geschrieben werden.

Fb<ModelName>.ModelParameters_<ParameterName>_Online

Referenzieren einer statischen Modul-Instanz:

Der FB kann genutzt werden, um auf vorher im XAE z. B. unter System > TcCOM Objects angelegte Modulinstanzen zuzugreifen. Für diesen statischen Fall muss die Objekt-ID der entsprechenden Modulinstanz bei der Deklaration der FB-Instanz übergeben werden:

fbStatic : FB_<ModuleName>(oid:=<ObjectId>);

Die Objekt-ID finden Sie in der Instanz des TcCOM unter dem Reiter Object.

Bespielcode

Das folgende Code-Beispiel zeigt die Verwendung eines modulspezifischen Funktionsbausteins in einem einfachen SPS-Programm in ST-Code am Beispiel eines Objektes der Modulklasse „TempContr“ mit der ObjectID 0x01010010:

PROGRAM MAIN
VAR
    // declare function block with ID of referenced Object
    fbTempContr : FB_TempContr(oid:= 16#01010010 );
    // input process image variable
    nInputTemperature AT%I* : INT;
    // output process image variable
    bHeaterOn AT%Q* : BOOL;
END_VAR
IF (fbTempContr.State = TCOM_STATE.TCOM_STATE_OP) THEN
    // set input values
    fbTempContr.stInput.FeedbackTemp := nInputTemperature;
    // execute module code
    fbTempContr.Execute();
    // get output values
    bHeaterOn := fbTempContr.stOutput.HeaterOn;
END_IF

Erzeugen und Referenzieren einer dynamischen Modul-Instanz:

Für den Fall <ObjectId> = 0, versucht der FB dynamisch eine Instanz des TcCom-Moduls zu erzeugen:

fbDynamic : FB_<ModuleName>(oid:=0);

In diesem Fall taucht die Modulinstanz nicht im Konfigurations-Baum des XAE auf, sondern erscheint erst zur Laufzeit (also nach der Initialisierung der SPS-Instanz) in der „Project Objects“-Tabelle des Knotens System > TcCOM Objects.

Voraussetzung für die dynamische Instanziierbarkeit eines TcCOM-Moduls ist, dass die zugehörige „Class Factory“ geladen ist. Dazu muss für die „Class Factory“ des Moduls unter dem Karteireiter Class Factories des Knotens System > TcCOM Objects die Checkbox Load (oder bei Verwendung des „TwinCAT Loaders“ die Checkbox TC Loader) gesetzt sein. Der Name der „Class Factory“ eines aus Simulink generierten TcCOM-Moduls ist in der Regel gleich dem Modulnamen, wobei der ClassFactory-Name allerdings auf weniger Zeichen begrenzt ist.

Weitere Voraussetzung für das dynamische Instanziieren eines Moduls ist die ausreichende Verfügbarkeit dynamischen Speichers. Dazu muss der ADS-Router-Speicher ausreichend groß gewählt sein.
Beispielcode:

PROGRAM MAIN
VAR
    // declare function block
    fbTempContr_Dyn : FB_TempContr(oid:= 0 );
    // input process image variable
    nInputTemperature AT%I* : INT;
    // output process image variable
    bHeaterOn AT%Q* : BOOL;
    // reset error code and reinitialize Object
    bReset: BOOL;
    // initialization helpers
    stInitData : ST_TempContr_InitData;
    bInitialized : BOOL;
END_VAR
IF (NOT bInitialized) THEN
    stInitData := fbTempContr_Dyn.InitData; // read default parameters
    // adapt required parameters:
    stInitData.ContextInfoArr_0_TaskOid := 16#02010020;    // oid of the plc task
    stInitData.ContextInfoArr_0_TaskCycleTimeNs := 10 * 1000000; // plc task cycle time in ns
    stInitData.ContextInfoArr_0_TaskPriority := 20; // plc task priority
    stInitData.CallBy := TctModuleCallByType.Module;
    stInitData.StepSize := TctStepSizeType.UseTaskCycleTime; 
    // set init data, copied to module the next time it switches from INIT to PREOP:
    fbTempContr_Dyn.InitData := stInitData;
    bInitialized := TRUE;
ELSIF (fbTempContr_Dyn.State<TCOM_STATE.TCOM_STATE_OP) THEN
    // try to change to OP mode
    fbTempContr_Dyn.State := TCOM_STATE.TCOM_STATE_OP;
ELSIF (NOT fbTempContr_Dyn.Error) THEN
    // set input values
    fbTempContr_Dyn.stInput.FeedbackTemp := nInputTemperature;
    // execute module code
    fbTempContr_Dyn.Execute();
    // get output values
    bHeaterOn := fbTempContr_Dyn.stOutput.HeaterOn;
END_IF

IF (bReset) THEN
    IF (fbTempContr_Dyn.Error) THEN
        fbTempContr_Dyn.ResetHresult();
    END_IF
    fbTempContr_Dyn.State := TCOM_STATE.TCOM_STATE_INIT;
END_IF

Import mehrerer PLCopen-XML: FB_TcMatSimObject

Der generische Baustein FB_TcMatSimObject ist für alle mit dem TE1400 (ab V1.2.12016.0) generierten Module gleich. Auch bei der Verwendung für unterschiedliche Module muss er nur einmal in das SPS-Project importiert werden.

Beschreibung des Funktionsbausteins:

Public Methods

Public Properties

Referenzierung einer Modul-Instanz

Auch FB_TcMatSimObject kann, genau wie der von ihm abgeleitete modulspezifische FB, mit der Objekt-ID einer statischen Modulinstanz oder mit 0 instanziiert werden:

fbStatic : FB_TcMatSimObject(oid:=<ObjectId>); // Referenz auf statisches TcCom-Objekt 

fbDynamic : FB_TcMatSimObject(oid:=0); // Erzeugen eines dynamisches TcCom-Objektes